PAL20L8
ICP16_new_pal_U60
VME-Z8002 CONTROL LOGIC
INTEGRATED SOLUTION INC., SAN JOSE, CA
/ZNMI I_O_WT /VCYCTERM /ZWORD /REGPRT LZA0 /VMECYC NC RCYCDTACK DTACK ZDS
GND /DEL_I_O_WT /ZWR /DVDS1 /DVDS0 /VDSE /ZWAIT VMIDTACK /WRN /RDN /SDTACK
VDS VCC

IF(VCC) /WRN = ZWR*ZDS
IF(VCC) /RDN = /ZWR*ZDS
IF(VCC) /SDTACK = REGPRT*ZWR*ZDS + SDTACK*REGPRT + RCYCDTACK + VMIDTACK
IF(VCC) /DVDS0 = LZA0*/ZWORD*VDSE + ZWORD*VDSE
IF(VCC) /DVDS1 = /LZA0*VDSE
IF(VCC) /ZWAIT = I_O_WT*/DEL_I_O_WT + ZWR*REGPRT*VDS 
                 + VMECYC*/ZNMI*/DTACK + VMECYC*DTACK*/VDSE*/ZNMI 
                 + VMECYC*VCYCTERM*/ZNMI*/VDSE
IF(VCC) /VDSE = VMECYC*ZDS*/DTACK + VDSE*ZDS

DESCRIPTION

The equation VDSE is acting as an RS flip flop where VMECYC* ZDS*/DTACK
is the set term and VDSE*ZDS is the reset term. This equation is necessary
to insure that only one VME data strobe is generated per VME dtack.
NOTE: VMIDTACK is an input to the pal. The corresponding I/O pin of the 
pal is configured as an input.
The /SDTACK equation also incorporates an RS flop. REGPRT*ZWR*ZDS is the
set term and SDTACK*REGPRT is the reset term. VME dtack needs to stay on
until REGPRT returns false. This is because REGPRT enables the VME data 
bus drivers.
