PAL16L8
ICP16_new_pal_U54
VME-ICP16 MEMORY MAP DECODER
INTEGRATED SOLUTION INC., SAN JOSE, CA
LZA13 /ZWORD /ZAS LZA0 VRST ZST3 /ZDS LZA14 /ZWR GND LZA15 /PROM /RAM_L
/RAM /RAM_H /VMECYC /ACCPRT /REGPRT /SPRTCTL VCC

IF (VCC) /PROM = /LZA13*/LZA14*/LZA15*ZST3*ZDS
IF (VCC) /RAM = LZA13*/LZA14*/LZA15*ZST3*ZDS + /LZA13*LZA14*/LZA15*ZST3*ZDS
IF (VCC) /SPRTCTL = LZA13*LZA14*/LZA15*ZST3
IF (VCC) /ACCPRT = /LZA13*/LZA14*LZA15*ZST3*ZDS
IF (VCC) /REGPRT = LZA13*/LZA14*LZA15*ZST3*/ZAS*/VRST
IF (VCC) /VMECYC = LZA14*LZA15*ZST3*/ZAS*/VRST
IF (VCC) /RAM_L = ZDS*ZWR*LZA0 + ZDS*ZWR*ZWORD
IF (VCC) /RAM_H = ZDS*ZWR*/LZA0 + ZDS*ZWR*ZWORD

DESCRIPTION

This PAL decodes the Z8002 memory mapped ports and the RAM write enable
lines, RAM_L and RAM_H. 
SPRTCTL monitors and controls the modem lines.
ACCPRT allows the Z8002 to decode register accesses by the host. 
REGPRT enables the Z8002 to transfer register data to and from the 
host in the vme slave mode.
VMECYC is used to transfer data to and from host memory in the vme
master mode.
PROM    =    0 - 1FFF H
RAM     = 2000 - 5FFF H
SPRTCTL = 6000 - 7FFF H
ACCPRT  = 8000 - 9FFF H
REGPRT  = A000 - BFFF H
VMECYC  = C000 - FFFF H
